/****************************************************************************
**
** Copyright (C) 2019 Luxoft Sweden AB
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company.  For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/

import QtQuick 2.12
import QtQuick.Controls 2.5

import shared.Sizes 1.0
import alexainterface 1.0

Control {
    id: root

    QtObject {
        id: privateData
        readonly property var headerText: ['a', 'm', 'a', 'z', 'o', 'n', ' ', 'a', 'l', 'e', 'x', 'a']
        property int headerTextIndex: 0
    }

    contentItem: Item {
        Row {
            id: animatedTextRow
            anchors.centerIn: parent
            anchors.verticalCenterOffset: Sizes.dp(50)
            spacing: Sizes.dp(35)
            Image {
                id: alexaLogo
                anchors.verticalCenter: parent.verticalCenter
                fillMode: Image.PreserveAspectFit
                height: root.height*0.25
                source: "assets/logo.png"
            }
            Label {
                id: alexaLogoText
                anchors.verticalCenter: parent.verticalCenter
                font.pixelSize: Sizes.fontSizeXXL
                font.letterSpacing: Sizes.dp(5)
                font.weight: Font.Medium
                opacity: 0.7
            }
        }
        Row {
            anchors.horizontalCenter: parent.horizontalCenter
            anchors.top: animatedTextRow.bottom
            anchors.topMargin: Sizes.dp(30)
            spacing: Sizes.dp(10)
            Rectangle {
                anchors.verticalCenter: parent.verticalCenter
                width: Sizes.dp(26)
                height: width
                radius: width/2
                color: AlexaInterface.connectionStatus === Alexa.Connected ? "#32CD32" :
                        (AlexaInterface.connectionStatus === Alexa.Disconnected) ?
                        "red" : "grey"
            }
            Label {
                anchors.verticalCenter: parent.verticalCenter
                font.pixelSize: Sizes.fontSizeS
                text: {
                    if (AlexaInterface.connectionStatus === Alexa.Pending)
                        return qsTr("Pending")
                    else if (AlexaInterface.connectionStatus === Alexa.Connected)
                        return qsTr("Connected")
                    else return qsTr("Disconnected")
                }
            }
        }
    }

    Timer {
        id: timerTextAnimation
        interval: 80
        repeat: true
        onTriggered: {
            var letter = privateData.headerText[privateData.headerTextIndex]
            alexaLogoText.text += privateData.headerText[privateData.headerTextIndex]
            privateData.headerTextIndex += 1
            if (privateData.headerTextIndex === privateData.headerText.length) {
                timerTextAnimation.stop()
            }
        }
    }

    Component.onCompleted: {
        timerTextAnimation.start()
    }
}