# Copyright 2015 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//build/config/features.gni")
import("//components/supervised_user/buildflags.gni")

static_library("browser_sync") {
  sources = [
    "active_devices_provider_impl.cc",
    "active_devices_provider_impl.h",
    "browser_sync_client.h",
    "browser_sync_switches.cc",
    "browser_sync_switches.h",
    "signin_confirmation_helper.cc",
    "signin_confirmation_helper.h",
    "sync_api_component_factory_impl.cc",
    "sync_api_component_factory_impl.h",
    "sync_client_utils.cc",
    "sync_client_utils.h",
  ]

  public_deps = [ "//components/sync" ]

  deps = [
    "//base",
    "//build:chromeos_buildflags",
    "//components/autofill/core/browser",
    "//components/autofill/core/common",
    "//components/bookmarks/browser",
    "//components/history/core/browser",
    "//components/history/core/common",
    "//components/password_manager/core/browser",
    "//components/power_bookmarks/core",
    "//components/power_bookmarks/core:features",
    "//components/prefs",
    "//components/reading_list/core",
    "//components/reading_list/features:flags",
    "//components/send_tab_to_self",
    "//components/supervised_user/core/common:buildflags",
    "//components/sync/invalidations",
    "//components/sync_bookmarks",
    "//components/sync_preferences",
    "//components/sync_sessions",
    "//components/sync_user_events",
    "//components/url_formatter",
    "//components/version_info",
    "//components/version_info:generate_version_info",
    "//ui/base",
  ]

  if (is_chromeos_ash) {
    deps += [
      "//ash/constants",
      "//components/desks_storage",
    ]
  }

  if (enable_supervised_users) {
    deps += [ "//components/supervised_user/core/browser" ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "active_devices_provider_impl_unittest.cc",
    "sync_client_utils_unittest.cc",
  ]

  deps = [
    ":browser_sync",
    "//base",
    "//base/test:test_support",
    "//components/autofill/core/browser:test_support",
    "//components/autofill/core/common",
    "//components/bookmarks/browser",
    "//components/bookmarks/managed",
    "//components/bookmarks/test",
    "//components/history/core/browser",
    "//components/password_manager/core/browser:test_support",
    "//components/prefs",
    "//components/reading_list/core:test_support",
    "//components/sync",
    "//components/sync:test_support",
    "//components/sync_bookmarks",
    "//components/sync_device_info",
    "//components/sync_device_info:test_support",
    "//components/version_info",
    "//components/version_info:generate_version_info",
    "//components/webdata/common",
    "//services/network:test_support",
    "//testing/gmock",
    "//testing/gtest",
  ]
}