# Copyright 2019 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

static_library("embedder_support") {
  sources = [
    "pref_names.h",
    "switches.cc",
    "switches.h",
  ]
}

# Target for general utilities that are only used in the browser process.
static_library("browser_util") {
  sources = [
    "content_settings_utils.cc",
    "content_settings_utils.h",
    "permission_context_utils.cc",
    "permission_context_utils.h",
    "user_agent_utils.cc",
    "user_agent_utils.h",
  ]

  deps = [
    ":embedder_support",
    "//build:branding_buildflags",
    "//components/background_sync",
    "//components/content_settings/browser",
    "//components/content_settings/core/browser",
    "//components/permissions",
    "//components/policy/core/common",
    "//components/prefs",
    "//components/version_info",
    "//content/public/browser",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "origin_trials/component_updater_utils_unittest.cc",
    "origin_trials/origin_trial_policy_impl_unittest.cc",
    "origin_trials/origin_trials_settings_storage_unittest.cc",
  ]

  if (!is_ios) {
    sources += [ "user_agent_utils_unittest.cc" ]
  }

  deps = [
    ":browser_util",
    "//base",
    "//base/test:test_support",
    "//build:branding_buildflags",
    "//components/component_updater/installer_policies",
    "//components/embedder_support",
    "//components/embedder_support/origin_trials",
    "//components/embedder_support/origin_trials:test_support",
    "//components/prefs",
    "//components/prefs:test_support",
    "//components/version_info:version_info",
    "//content/public/common",
    "//mojo/core/embedder:embedder",
    "//net:net",
    "//net/traffic_annotation:test_support",
    "//services/network:test_support",
    "//testing/gtest",
    "//third_party/blink/public/common:headers",
    "//third_party/blink/public/mojom:mojom_platform_headers",
    "//third_party/re2",
  ]

  if (is_android) {
    sources += [
      "android/util/android_stream_reader_url_loader_unittest.cc",
      "android/util/input_stream_reader_unittest.cc",
      "android/util/input_stream_unittest.cc",
    ]

    deps += [
      "android:native_j_unittests_jni_headers",
      "android:native_java_unittests_java",
      "android:util",
    ]
  }
}