scripts/vstools/msbuild.cmd


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

:: Copyright (C) 2025 The Qt Company Ltd.
:: SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::msbuild.cmd
:: * Solution main build
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

IF "%BUILD_PLATFORM%" == "" (
    SET BUILD_PLATFORM=%VSCMD_ARG_TGT_ARCH%
)

ECHO.
%##########################%
%##% %BOLD%Building...%RESET%
%##% msbuild: vstools.sln
%##% msbuild: -t:%MSBUILD_TARGETS%
%##% msbuild: -p:Configuration=%BUILD_CONFIGURATION%
%##% msbuild: -p:Platform=%BUILD_PLATFORM%
IF %VERBOSE% (
    %##% msbuild: -p:TransformOutOfDateOnly=%TRANSFORM_INCREMENTAL%
    %##% msbuild: -verbosity:%MSBUILD_VERBOSITY%
    %##% msbuild extras: %MSBUILD_EXTRAS%
)
%##########################%
IF NOT %VERBOSE% ECHO %DARK_GRAY%
msbuild ^
    -nologo ^
    -verbosity:%MSBUILD_VERBOSITY% ^
    -maxCpuCount ^
    -p:Configuration=%BUILD_CONFIGURATION% ^
    -p:Platform=%BUILD_PLATFORM% ^
    -p:TransformOutOfDateOnly=%TRANSFORM_INCREMENTAL% ^
    -t:%MSBUILD_TARGETS% ^
    %MSBUILD_EXTRAS% ^
    vstools.sln
ECHO %RESET%
IF %ERRORLEVEL% NEQ 0 (
    CALL %SCRIPTLIB%\error.cmd %ERRORLEVEL% "ERROR building solution"
    EXIT /B %ERRORLEVEL%
)

CALL %SCRIPTLIB%\info.cmd "version"
%##% %BOLD%%GREEN%Solution build successful.%RESET%
%##########################%