blob: 8482168b5a5de026a96170bf5e075c01416c5890 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
// Copyright (c) 2012 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#import "ui/base/cocoa/fullscreen_window_manager.h"
namespace {
// Get the screen with the menu bar.
NSScreen* GetMenuBarScreen() {
// Documentation in NSScreen says that the first object in
// +[NSScreen screens] is the menu bar screen.
NSArray *screens = [NSScreen screens];
if ([screens count])
return [screens objectAtIndex:0];
return nil;
}
// Get the screen with the dock.
NSScreen* GetDockScreen() {
NSArray *screens = [NSScreen screens];
NSUInteger count = [screens count];
if (count == 0)
return NULL;
if (count == 1)
return [screens objectAtIndex:0];
for (NSUInteger i = 1; i < count; ++i) {
NSScreen* screen = [screens objectAtIndex:i];
// This screen is not the menu bar screen since it's not index 0. Therefore,
// the only reason that the frame would not match the visible frame is if
// the dock is on the screen.
if (!NSEqualRects([screen frame], [screen visibleFrame]))
return screen;
}
return [screens objectAtIndex:0];
}
} // namespace
@interface FullscreenWindowManager()
- (void)onScreenChanged:(NSNotification*)note;
- (void)update;
@end
@implementation FullscreenWindowManager
- (id)initWithWindow:(NSWindow*)window
desiredScreen:(NSScreen*)desiredScreen {
if ((self = [super init])) {
window_.reset([window retain]);
desiredScreen_.reset([desiredScreen retain]);
fullscreenMode_ = base::mac::kFullScreenModeNormal;
[[NSNotificationCenter defaultCenter]
addObserver:self
selector:@selector(onScreenChanged:)
name:NSApplicationDidChangeScreenParametersNotification
object:NSApp];
}
return self;
}
- (void)dealloc {
[[NSNotificationCenter defaultCenter] removeObserver:self];
[self exitFullscreenMode];
[super dealloc];
}
- (void)enterFullscreenMode {
if (fullscreenActive_)
return;
fullscreenActive_ = true;
[self update];
}
- (void)exitFullscreenMode {
if (!fullscreenActive_)
return;
fullscreenActive_ = false;
[self update];
}
- (void)onScreenChanged:(NSNotification*)note {
[self update];
}
- (void)update {
if (![[NSScreen screens] containsObject:desiredScreen_])
desiredScreen_.reset([[window_ screen] retain]);
base::mac::FullScreenMode newMode;
if (!fullscreenActive_)
newMode = base::mac::kFullScreenModeNormal;
else if (desiredScreen_ == GetMenuBarScreen())
newMode = base::mac::kFullScreenModeHideAll;
else if (desiredScreen_ == GetDockScreen())
newMode = base::mac::kFullScreenModeHideDock;
else
newMode = base::mac::kFullScreenModeNormal;
if (fullscreenMode_ != newMode) {
if (fullscreenMode_ != base::mac::kFullScreenModeNormal)
base::mac::ReleaseFullScreen(fullscreenMode_);
if (newMode != base::mac::kFullScreenModeNormal)
base::mac::RequestFullScreen(newMode);
fullscreenMode_ = newMode;
}
if (fullscreenActive_)
[window_ setFrame:[desiredScreen_ frame] display:YES];
}
@end
|
