windows batch, setting a variable inside a nested loop

Question

I have the below batch that reads data from a text file, the problem is in the inner loop; it should get the lat created file in the destination folder, and it just gets nothing!

here's my code:

:: Delete Files from folder
@echo off
:: Delete Files from folder
echo y | del "E:\HIS_Data_Consolidation\HIS_Backups\*.bak" 
echo Deleting previous bak files...
set destdir=E:\HIS_Data_Consolidation\HIS_Backups
setlocal
FOR /F "tokens=1,2,3 delims=," %%G IN (clinics.txt) DO (
pushd "%%G"
for /F  "tokens=*" %%a in ('dir *.* /b /a-d /o:e 2^>NUL') do (
set lfile=%%a
)
echo copying "%%G\%lfile%" to "%destdir%" ,,,%%H
copy /y "%%G\%lfile%" "%destdir%
E:
cd "%destdir%
E:\HIS_Data_Consolidation\HIS_Backups\unrar.exe e "%destdir%/%lfile%"
echo y | del "E:\HIS_Data_Consolidation\HIS_Backups\*.rar" 
echo Deleting RAR file...
SET v_test=%lfile%
SET v_result=%v_test:rar=bak%
ren "%v_result%"  "%%I"
echo Ready ...
popd
)
pause

appreciate you help. thanks.

npocmaka · Accepted Answer · 2012-12-03 08:08:38Z

2

If you'are using a set inside for body you'll need enabledelayedexpansion: http://www.robvanderwoude.com/variableexpansion.php

edit:

:: Delete Files from folder
@echo off
:: Delete Files from folder
echo y | del "E:\HIS_Data_Consolidation\HIS_Backups\*.bak" 
echo Deleting previous bak files...
set destdir=E:\HIS_Data_Consolidation\HIS_Backups

setlocal enabledelayedexpansion
FOR /F "tokens=1,2,3 delims=," %%G IN (clinics.txt) DO (
    pushd "%%G" 
    for /F  "tokens=*" %%a in ('dir *.* /b /a-d /o:e 2^>NUL') do (
        set lfile=%%a
    )
    echo copying "%%G\!lfile!" to "!destdir!" ,,,%%H
    copy /y "%%G\!lfile!" "!destdir!"
    E:
    cd "!destdir!"
    E:\HIS_Data_Consolidation\HIS_Backups\unrar.exe e "!destdir!/!lfile!"
    echo y | del "E:\HIS_Data_Consolidation\HIS_Backups\*.rar" 
    echo Deleting RAR file...
    SET v_test=!lfile!
    SET v_result=!v_test:rar=bak!
    ren "!v_result!"  "%%I"
    echo Ready ...
    popd
)
endlocal
pause

edited Dec 3, 2012 at 8:08

answered Dec 2, 2012 at 12:27

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

majd_wadi Over a year ago

aha, thanks for your reply ...i will try it tomorrow as soon as i arrive to my office and let u know what happens

majd_wadi Over a year ago

Hi Again, it didn't work, i put the sentence before the loop and inside the loop, the value changes as long as it is inside the loops and when i use it after the loop finishes; i get an empty value.

npocmaka Over a year ago

have you changed the variable access with !variable! instead of %variable% ?

Mureinik · Accepted Answer · 2014-04-13 06:25:54Z

0

@npocmaka Thank you! You solved my problem I was working on for hours! I had a similar problem.

I was using a nested for loop and tried to split the for loop into another batch file, but didn't work. So I used 'npocmaka's advice:

This is the batch being called which is inside another for loop.

@ECHO OFF


SET dir=%~1
SET suf=%~2

ECHO IN dir:%dir%
ECHO IN suf:%suf%
PAUSE

SET /A count=1

SETLOCAL EnableDelayedExpansion
pushd %dir%
FOR /R . %%A IN (*.%suf%) DO (

    ECHO File: %%~nxA count:!count!
    PAUSE
    REN %%~nxA !count!.txt
    CALL :increment RESULT count
)
popd
ENDLOCAL


:increment
SET /A count+=1

edited Apr 13, 2014 at 6:25

Mureinik

316k54 gold badges402 silver badges406 bronze badges

answered Apr 13, 2014 at 6:02

ejbytes

1831 silver badge9 bronze badges

Collectives™ on Stack Overflow

windows batch, setting a variable inside a nested loop

2 Answers 2

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related