Why is my script only accessing the first element in array?

It's a little hard to answer with certainty without more information about the contents of @barcode and FILE, but there is something odd in your code which makes me think that it might be the problem.

The construct while (<FILE>) { ... } will, until end of file, read a line from FILE into $_ and then execute the contents of the loop. In your code, you also read all the lines from FILE from within the loop that iterates over @barcode. I think it is likely that you intended to check each line from FILE against all the elements of @barcode, which would make the loop look like the following:

while (my $line = <FILE>) {
    foreach my $barcode (@barcode) {
        if ($line =~ /Barcode([0-9]*)\t$barcode/) {
            my $bar = $1;
            print OUT ">Barcode$bar"."_"."$barcode\n";
        }
        else {
            print OUT $line;
        }
    }
}

I've taken the liberty of doing a bit of code tidying, but I may have made some unwarranted assumptions.

Your core problem in the above is - in your first iteration you slurp all of your file into @lines. But because it's lexically scoped to the loop, it disappears when that loop completes.

Furthermore:

• I would strongly suggest that you don't use $_ like that.

$_ is a special variable that's set implicitly in loops. I'd strongly suggest that you need to replace that with something that isn't a special variable, because that's a sure way to cause yourself pain.

• turn on use strict; and use warnings;

• use 3 argument open with a lexical filehandle.

• perltidy your code, so the bracketing looks right.

• you've a search and replace pattern on $_ that's emptying it completely, but then you're trying to print it. You may well not be printing what you think you're printing.

• You're accessing <FILE> outside and inside your loop. This will cause you problems.

  • Barcode([0-9]*) - with a '*' there you're saying 'zero or more' is valid. You may want to consider \d+ - one or more digits.

  • referencing multiple arrays by index is messy. I'd suggest coalescing them into a hash lookup (lookup by key - barcode)

This line:

my @line = <FILE>;

reads your whole file into @line. But you do this inside the while loop that iterates... each line in <FILE>. Don't do that, it's horrible.

Is this something like what you wanted?

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my @barcode = qw (
    001
    002
    003
);

my @otherarray = qw (
    abc
    def
    ghi
);

my %lookup;
@lookup{@barcode} = @otherarray;

print Dumper \%lookup;

#commented because I don't have your source data
#my $file   = "input_file_name";
#my $output = "output_file_name";

#open( my $input,  "<", $file )  or die "\nNot opening $file for reading\n\n";
#open( my $output, ">", $final ) or die "Did not open $final\n";

#while ( my $line = <$input> )
while ( my $line = <DATA> ) {
    foreach my $barcode (@barcode) {
        if ( my ($bar) = ( $line =~ /Barcode(\d+)\s+$barcode/ ) ) {
            print ">Barcode$bar" . "_" . "$barcode $lookup{$barcode}\n";
            #print {$output} ">Barcode$bar" . "_" . "$lookup{$barcode}\n";
        }
    }
}

__DATA__
Barcode001    001
Barcode002    002
Barcode003    003

Prints:

$VAR1 = {
          '001' => 'abc',
          '002' => 'def',
          '003' => 'ghi'
        };
>Barcode001_001 abc
>Barcode002_002 def
>Barcode003_003 ghi