I have written a Clojure function that can successfully sort a list of lists according to length frequency.
However, I don't like the way it is written. Does anyone have any suggestions for writing this in a different way?
(defn lfsort [n]
(let [total (frequencies (map #(count %) n))]
(sort #(< (total (count %1)) (total (count %2))) n)))
(lfsort '((a b c) (d e) (f g h) (d e) (i j k l) (m n) (o)))
((i j k l) (o) (a b c) (f g h) (d e) (d e) (m n))
Kind Regards, Ben.
(defn lfsort [coll]
(sort-by (comp (frequencies (map count coll))
count)
coll))
How do we get here from your solution? First, note that (sort #(< (f %1) (f %2)) xs) is just (sort-by f xs). Then, since we only actually need to use the result of the frequencies call once, we can just inline it, and compose it with count to get our sort-by function.
You may or may not find this more readable than your posted solution; you can choose a middle ground by not inlining the frequencies call, but I think it's definitely better to use sort-by and comp than to spell out the sort lambda yourself.
Another way to do it is:
(defn lfsort [n]
(->> n
(group-by count)
vals
(sort-by count)
(apply concat)))
For example,
(lfsort '((a b c) (d e) (f g h) (d e) (i j k l) (m n) (o)))
;((i j k l) (o) (a b c) (f g h) (d e) (d e) (m n))
I find this clearer. You may or may not.
@amalloys's