How can I set my variable in windows batch file?

Question

I used this script:

rem @echo off
SETLOCAL enableDelayedExpansion
Set crs=
REM Get the result from sl.txt
FIND "LISTENER_SCAN1" <sl.txt >sl_temp_01.txt
FIND "running" <sl_temp_01.txt >sl_final.txt
DEL sl_temp_01.txt
for /F "tokens=8 delims= " %%j in (sl_final.txt) do (
IF %%J EQU "40" (SET crs=crs1)
IF %%J EQU "41" (SET crs=crs2)
IF %%J EQU "42" (SET crs=crs3)
IF %%J EQU "43" (SET crs=crs4)
Echo %%j
Echo !crs!
Pause
)

I can get echo %%j as 42 this time, but I cannot set my variable crs as crs3. Could you please help? Thanks,

score 2 · Accepted Answer · 2018-06-27 20:10:36Z

If %%J already contained enclosing double quotes your if could be valid, if not this is never true.
To be sure use the ~ modifier to strip possible double quotes and set them yourself.

IF "%%~J" EQU "40" (SET crs=crs1)

Also %%J and %%j are distinct meta variables - in your batch you use them once in lowercase and then uppercase.
If variables are possibly empty put a different command separator behind the echo (= for example - not a space. This would return echo is on/off then.
There is no need for intermediate files, stack two find commands and parse the output with the for /f

:: Q:\Test\2018\06\27\SO_51067292.cmd
@echo off & SETLOCAL enableDelayedExpansion
Set "crs="

for /F "tokens=8 delims= " %%J in (
    'FIND "LISTENER_SCAN1" ^<sl.txt ^| FIND "running"'
) do (
    IF "%%~J" EQU "40" (SET crs=crs1)
    IF "%%~J" EQU "41" (SET crs=crs2)
    IF "%%~J" EQU "42" (SET crs=crs3)
    IF "%%~J" EQU "43" (SET crs=crs4)
    Echo=%%J
    Echo=!crs!
    Pause
)

Collectives™ on Stack Overflow

How can I set my variable in windows batch file?

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related