Why doesn't java_binary propagate runtime dependencies to java_test

Question

I wrote a small application and used java_binary as follows:

java_binary(
    name = "MyCommand",
    srcs = [
        "MyCommand.java",
    ],
    visibility = ["//visibility:public"],
    deps = [
        "//src/main/java/com/example/two",
    ],
)

It depends on a java_library target //src/main/java/com/example/two

I then wrote a java_test as follows:

java_test(
    name = "TestMyCommand",
    size = "small",
    srcs = [
        "TestMyCommand.java",
    ],
    deps = [
        ":MyCommand",
    ],
)

The test is pretty simple and just does new MyCommand().

This unfortunately fails quickly with a ClassDefNotFoundException with a class file found in //src/main/java/com/example/two. Setting a breakpoint it looks like that library is not included in the ClassPath.

HOWEVER, if I change my java_test to depend on a java_library THEN the transitive dependency of //src/main/java/com/example/two is included.

I could not find anything in the documentation explaining why?

ahumesky · Accepted Answer · 2022-08-04 04:24:02Z

1

This is because java_binary is a "binary" rule, i.e., it outputs an executable, or another way, it's typically a "terminal" or "root" rule. So it doesn't pass along the info to add its deps to the final classpath, because it doesn't typically expect to be in the dependencies[1] of other targets (even java_test).

You could refactor the BUILD file so that MyCommand.java is in a java_library, and the java_test and the java_binary targets depend on that:

java_binary(
    name = "MyCommandMain",
    runtime_deps = [":MyCommand"],
    main_class = "com.example.one.MyCommand",
)

java_library(
    name = "MyCommand",
    srcs = [
        "MyCommand.java",
    ],
    visibility = ["//visibility:public"],
    deps = [
        "//src/main/java/com/example/two",
    ],
)

1: But you do sometimes see things like this:

# or other kinds of binary rules (cc_binary, py_binary, etc)
java_binary(
  name = "my_java_bin",
  ...,
)

sh_binary(
  name = "my_shell_script",
  srcs = ["script.sh"],
  data = [":my_java_bin"],
)

and script.sh runs my_java_bin as part of whatever it's accomplishing. The difference here is that my_shell_script is using the whole binary, rather than programming against code within it.

answered Aug 4, 2022 at 4:24

ahumesky

5,07611 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

Setheron Over a year ago

how does the sh_binary work if it does not get the transitive dependencies also ? It needs them for runtime... Is there a flag to control this? I find this distinction strange...

ahumesky Over a year ago

One of the outputs of a binary rule is its so-called "runfiles", the files needed to run the executable. The sh_binary receives those files (i.e., bazel sets up all those files in the sh_binary's exec root for bazel run), and in the case of java_binary, those are a wrapper script that invokes java with the right arguments and jars, and the collection of jars for the application. How the java rules decide what should be on the class path (compile time classpath, runtime classpath, or both) is separate.

ahumesky Over a year ago

Regarding a flag, what behavior specifically are you looking to change?

Setheron Over a year ago

Propagate the runtime deps like java_library

ahumesky Over a year ago

I'm pretty sure this is working as intended (e.g. github.com/bazelbuild/bazel/issues/11705 and github.com/bazelbuild/bazel/issues/12836), but maybe java_test depending on a java_binary is worth some consideration, so feel free to open a feature request: github.com/bazelbuild/bazel/issues/…

Collectives™ on Stack Overflow

Why doesn't java_binary propagate runtime dependencies to java_test

1 Answer 1

5 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

5 Comments

Your Answer

Sign up or log in

Post as a guest

Related