Create multiple data disks with VM in availability zones Issue

Create multiple data disks with VM in availability zones Issue while using terraform.

The Issue you're facing the is because 'count' and 'for_each' together which in practical not possible in terraform and also incorrect use of for_each which is used fetch the respective keys.

To overcome this issue, I tried make changes by using same for_each function for VM creation, disks & its attachments. Then passing locals in creating the disks for every VM.

Terraform Configuration:

main.tf:

provider "azurerm" {
  features {}
}

resource "azurerm_resource_group" "rg" {
  name     = var.resource_group_name
  location = var.location
}

resource "azurerm_network_interface" "nic" {
  for_each            = { for idx, az in var.availability_zones : idx => az }
  name                = "${var.vm_name}-${each.value}-nic"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name

  ip_configuration {
    name                          = "${var.vm_name}-${each.value}-ipConfig"
    subnet_id                     = var.subnet_id
    private_ip_address_allocation = "Static"
    private_ip_address            = var.static_ip_addresses[each.key]
  }
}

resource "azurerm_virtual_machine" "vm" {
  for_each            = { for idx, az in var.availability_zones : idx => az }
  name                = "${var.vm_name}-${each.value}"
  location            = azurerm_resource_group.rg.location
  resource_group_name = azurerm_resource_group.rg.name
  network_interface_ids = [azurerm_network_interface.nic[each.key].id]
  vm_size             = var.size
  zones               = [each.value]

  identity {
    type = "SystemAssigned"
  }

  storage_os_disk {
    name              = "${var.vm_name}-${each.value}-osDisk"
    caching           = var.os_disk_caching
    create_option     = "FromImage"
    managed_disk_type = var.os_managed_disk_type
    disk_size_gb      = var.os_disk_size_gb
  }

  os_profile {
    computer_name  = "${var.vm_name}-${each.value}"
    admin_username = var.admin_username
    admin_password = var.admin_password
  }

  storage_image_reference {
    publisher = var.image_publisher
    offer     = var.image_offer
    sku       = var.image_sku
    version   = var.image_version
  }

  os_profile_windows_config {
    provision_vm_agent        = true
    enable_automatic_upgrades = true
  }

  delete_os_disk_on_termination    = true
  delete_data_disks_on_termination = true

  tags = var.tags
}

locals {
  data_disks = flatten([
    for vm_key, az in var.availability_zones : [
      for disk_num in range(1, var.data_disk_count + 1) : {
        name     = "${var.vm_name}-${az}-DataDisk-${disk_num}"
        zone     = az
        vm_key   = vm_key
        disk_num = disk_num
      }
    ]
  ])
}

resource "azurerm_managed_disk" "data_disk" {
  for_each = { for disk in local.data_disks : "${disk.vm_key}-${disk.disk_num}" => disk }

  name                 = each.value.name
  location             = azurerm_resource_group.rg.location
  resource_group_name  = azurerm_resource_group.rg.name
  storage_account_type = var.data_disk_storage_account_type
  create_option        = "Empty"
  disk_size_gb         = var.data_disk_size_gb
  zone                 = each.value.zone
  tags                 = var.tags
}

resource "azurerm_virtual_machine_data_disk_attachment" "data_disk_attachment" {
  for_each = { for disk in local.data_disks : "${disk.vm_key}-${disk.disk_num}" => disk }

  virtual_machine_id = azurerm_virtual_machine.vm[each.value.vm_key].id
  managed_disk_id    = azurerm_managed_disk.data_disk[each.key].id
  lun                = each.value.disk_num + 4
  caching            = var.data_disk_caching
}

Variable.tf:

 variable "resource_group_name" {
  description = "The name of the resource group"
  type        = string
}

variable "location" {
  description = "The location of the resource group"
  type        = string
}

variable "vm_name" {
  description = "The name of the virtual machine"
  type        = string
}

variable "subnet_id" {
  description = "The subnet ID for the VM"
  type        = string
}

variable "size" {
  description = "The size of the virtual machine"
  type        = string
}

variable "os_disk_caching" {
  description = "The caching type for the OS disk"
  type        = string
}

variable "os_managed_disk_type" {
  description = "The type of the OS managed disk"
  type        = string
}

variable "os_disk_size_gb" {
  description = "The size of the OS disk in GB"
  type        = number
}

variable "admin_username" {
  description = "The admin username for the VM"
  type        = string
}

variable "admin_password" {
  description = "The admin password for the VM"
  type        = string
}

variable "image_publisher" {
  description = "The publisher of the VM image"
  type        = string
}

variable "image_offer" {
  description = "The offer of the VM image"
  type        = string
}

variable "image_sku" {
  description = "The SKU of the VM image"
  type        = string
}

variable "image_version" {
  description = "The version of the VM image"
  type        = string
}

variable "tags" {
  description = "Tags to apply to resources"
  type        = map(string)
}

variable "data_disk_count" {
  description = "The number of data disks to attach to the VM"
  type        = number
}

variable "data_disk_size_gb" {
  description = "The size of the data disks in GB"
  type        = number
}

variable "data_disk_storage_account_type" {
  description = "The storage account type for the data disks"
  type        = string
}

variable "data_disk_caching" {
  description = "The caching type for the data disks"
  type        = string
}

variable "availability_zones" {
  description = "The availability zones for the VMs"
  type        = list(string)
}

variable "static_ip_addresses" {
  description = "The static IP addresses to assign to the NICs"
  type        = list(string)
}

Deployement succedded:

reference:

https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/virtual_machine_data_disk_attachment