Batch check for empty user input

Question

I am struggling with a simple check if the user input was just empty (Enter) and in case set the variable to a new value... spend an hour but it does not work. Goal is to have the entered Value beginning with a backslash OR just an empty string if nothing was entered.

Code:

SET myTargetServerInstanceName=anyNOPEdummyValue
SET /P myTargetServerInstanceName=Enter Target Server INSTANCE Name:    
IF %myTargetServerInstanceName%==anyNOPEdummyValue SET myTargetServerInstanceName=
IF NOT %myTargetServerInstanceName% == [] SET myTargetServerInstanceName=\%myTargetServerInstanceName%

this results in error:

SET was unexpected at this time.

Aacini · Accepted Answer · 2015-09-09 15:14:32Z

19

The usual way to check for an empty variable is compare if its "%value%" is "". However, in order for this to work you must delete the variable before the set /P, because if the user just press enter the previous value of the variabe is not modified:

set "var="
set /P var=
if "%var%" equ "" set "var=default value"

However, a simpler method is use if defined:

set "var="
set /P var=
if not defined var set "var=default value"

Previous method would not require delayed expansion.

As a corollary of previous description, you may get the same result this way:

set "var=default value"
set /P var=

answered Sep 9, 2015 at 15:14

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Magier Over a year ago

This indicated to the right direction. The following is working for me: IF [%myTargetServerInstanceName%] == [] SET myTargetServerInstanceName = \%myTargetServerInstanceName%

MC ND · Accepted Answer · 2015-10-14 10:51:48Z

3

You can check if the set /p operation was sucessful

set /p "var=prompt text?" || set "var=default value"

If you prefer the set / if, when you check for a value that can be empty or contain spaces, it is better to use quotes

if "%var%"=="" set "var=default value"

or, as a variable without content is not defined, you can check this case with

if not defined var set "var=default value"

edited Oct 14, 2015 at 10:51

answered Sep 9, 2015 at 14:39

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

1 Comment

S.Serpooshan Dec 31, 2024 at 7:11

Good trick to set default value. But when I test different values, it seems that the quotes are not required even if the values contains spaces! Are you sure the format {set /p var=prompt text:} or set var=default value with space may have errors in some cases? I'm not happy to put quote before the var name (as we always expect put quotes around the value itself not the var)

aschipfl · Accepted Answer · 2015-09-09 13:37:27Z

0

I suggest to enclose both sides of the if comparison parts in ":

SET myTargetServerInstanceName=anyNOPEdummyValue
SET /P myTargetServerInstanceName=Enter Target Server INSTANCE Name:    
IF "%myTargetServerInstanceName%"=="anyNOPEdummyValue" SET myTargetServerInstanceName=
IF NOT "%myTargetServerInstanceName%"=="" SET myTargetServerInstanceName=\%myTargetServerInstanceName%

If one of the comparison expressions (left or right of the ==) expands to an empty string, you will receive a syntax error.

answered Sep 9, 2015 at 13:37

aschipfl

35.3k12 gold badges62 silver badges106 bronze badges

Collectives™ on Stack Overflow

Batch check for empty user input

3 Answers 3

1 Comment

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related