How to check for multiple empty variable in batch

Question

I using multiple variables in a batch file, I need to check if they contains any value.

Currently I am using:-

IF [%TEST%] == [] (
echo The Value of Test is empty!
exit /b )

But using this is increasing the lines of code, is there a some way like OR in batch that can be used (like we do for shell).

A variable cannot have no value, it is either defined, (i.e. it has a value), or it is not defined. Example: If Not Defined TEST Echo TEST is not defined. In the example above by Gerhard, you don't need an if, because only defined variables would be passed from the For set, in the parentheses. — Compo
– Compo, Commented Sep 11, 2018 at 7:44
How about a for loop? for %%i in (%var1% %var2% %var3%) do echo %%i to only echo variables that are defined, as mentioned by @Compo . I deleted original comment to repost and remove if — user7818749
– user7818749, Commented Sep 11, 2018 at 7:56

score 4 · Accepted Answer · 2018-09-11 13:08:52Z

4

I think the easiest would be to simply create a for loop and test each value. So consider the following:

If you want to do nothing if a value is empty (undefined), and simply use the variable's value, which are defined:

@echo off
set "test1=Value1"
set "test2=Value2"
set "test3="
set "test4=Value4"
set "myvars=%test1% %test2% %test3% %test4%"

for %%i in (%myvars%) do echo %%i

If you actually want to only test if a variable is undefined or not:

@echo off
set "test1=Value1"
set "test2=Value2"
set "test3="
set "test4=Value4"
set "myvars=test1 test2 test3 test4"

for %%i in (%myvars%) do if not defined %%i (echo %%i not defined) else echo %%i Defined

or if you simply want to rather include the variables in the loop and not assign them to a single variable:

@echo off
set "test1=Value1"
set "test2=Value2"
set "test3="
set "test4=Value4"

for %%i in (test1 test2 test3 test4) do if not defined %%i (echo %%i not defined) else echo %%i Defined

edited Sep 11, 2018 at 13:08

answered Sep 11, 2018 at 8:05

user7818749

Sign up to request clarification or add additional context in comments.

2 Comments

DodgyCodeException Over a year ago

The first example simply prints test1, newline, test2 newline, etc. You're not actually getting the values, only the names.

user7818749 Over a year ago

@DodgyCodeException Thanks, forgot to test it. fixed.

Aacini · Accepted Answer · 2018-09-11 18:07:50Z

4

I think the simplest way is this:

if "%test1%%test2%%test3%" equ "" ( 
   echo The three variables are empty!
   exit /b
)

EDIT: Additional tests added

Ok. The code below check that at least one of the variables is not empty:

if "%test1%%test2%%test3%" neq "" ( 
   echo At least one variable is not empty!
   exit /b
)

And the next code check that at least one of the variables is empty:

set "allVars=|%test1%|%test2%|%test3%|"
if "%allvars:||=%" neq "%allVars%" (
    echo At least one variable is empty
)

In the last code it is necessary to select a delimiter character that can not appear in any variable.

edited Sep 11, 2018 at 18:07

answered Sep 11, 2018 at 12:32

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

4 Comments

user7818749 Over a year ago

This will only test if all 3 variables are empty, not only one? OP specifically specifies OR.

dbenham Over a year ago

@GerhardBarnard - add an ELSE and you can also take action if at least one variable is defined (not empty), which may be all the OP needs. Impossible to tell because the original question is vague on the specific goal.

user7818749 Over a year ago

@dbenham I agree yes, but op says like using an OR, so he wants if test1 or if test or... so in this case, else will do yes, but it is not included, hence my comment to Aacini to perhaps clarify :)

dbenham Over a year ago

@GerhardBarnard - Strike my previous comment. The OP most likely needs to know if at least one variable is undefined, which cannot be determined with this technique.

Collectives™ on Stack Overflow

How to check for multiple empty variable in batch

2 Answers 2

2 Comments

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related